A374376 Array read by downward antidiagonals: T(k,n) is the least number that has k prime factors (counted with multiplicity) and is the concatenation of n primes, or -1 if there is no such number.

2, 23, -1, 223, 22, -1, 2237, 235, 27, -1, 22273, 2227, 222, 132, -1, 222323, 22223, 2222, 225, 32, -1, 2222273, 222223, 22222, 2223, 252, 729, -1, 22222223, 2222557, 222227, 22225, 2322, 352, 192, -1, 222222227, 22222237, 2222222, 222225, 22232, 2232, 2352, 2112, -1, 2222222377, 222222223

Offset

1,1

References

T(k,1) = -1 for k > 1.

Links

Table of n, a(n) for n=1..47.

Example

Array starts
  2  23   223   2237   22273  ...
 -1  22   235   2227   22223  ...
 -1  27   222   2222   22222  ...
 -1 132   225   2223   22225  ...
 -1  32   252   2322   22232  ...
A(4,3) = 225 because 225 = 3^2 * 5^2 is the product of 4 primes (with multiplicity) and is the concatenation of the 3 primes 2, 2 and 5, and is the least number that works.

Maple

PD[1]:= [2, 3, 5, 7]:
for i from 2 to 7 do PD[i]:= select(isprime, [seq(i, i=10^(i-1)+1..10^i-1, 2)]) od:
dcat:= proc(a, b) 10^(ilog10(b)+1)*a+b end proc:
cp:= proc(m, n) option remember; local d, p, x, R;
  if n = 1 then return PD[m] fi;
  R:= {};
  for d from 1 to m-n+1 do
    R:= R union {seq(seq(dcat(p, x), p=PD[d]), x=procname(m-d, n-1))}
  od;
  R
end proc:
F:= proc(n, N)
local V, count, d, x, v;
if n = 1 then return <2, (-1)$(N-1)> fi;
V:= Vector(N); count:= 0;
for d from n while count < N do
  for x in sort(convert(cp(d, n), list)) while count < N do
    v:= numtheory:-bigomega(x);
    if v <= N and V[v] = 0 then
      V[v]:= x; count:= count+1;
    fi
od od:
V;
end proc:
N:= 10: M:= Matrix(N, N):
for i from 1 to N do
  V:= F(i, N+1-i);
  M[i, 1..N+1-i]:= V;
od:
[seq(seq(M[t-i, i], i=1..t-1), t=2..N+1)];

Crossrefs

Cf. A001222, A069837 (first row), A374665 (main diagonal), A374669 (second column).

Sequence in context: A261198 A052077 A124604 * A329336 A323396 A359272

Adjacent sequences: A374373 A374374 A374375 * A374377 A374378 A374379

Keyword

sign,base

Author

Robert Israel, Jul 14 2024

Status

approved