A255231 The number of factorizations n = Product_i b_i^e_i, where all bases b_i are distinct, and all exponents e_i are distinct >=1.

1, 1, 1, 2, 1, 1, 1, 2, 2, 1, 1, 2, 1, 1, 1, 4, 1, 2, 1, 2, 1, 1, 1, 3, 2, 1, 2, 2, 1, 1, 1, 5, 1, 1, 1, 4, 1, 1, 1, 3, 1, 1, 1, 2, 2, 1, 1, 5, 2, 2, 1, 2, 1, 3, 1, 3, 1, 1, 1, 2, 1, 1, 2, 7, 1, 1, 1, 2, 1, 1, 1, 6, 1, 1, 2, 2, 1, 1, 1, 5, 4, 1, 1, 2, 1, 1, 1, 3, 1, 2, 1, 2, 1, 1, 1, 6, 1, 2, 2, 4, 1, 1, 1, 3, 1, 1, 1, 6, 1, 1, 1, 5, 1, 1, 1, 2, 2, 1, 1, 3

Offset

1,4

Comments

Not multiplicative: a(48) = a(2^4*3) = 5 <> a(2^4)*a(3) = 4*1 = 4. - R. J. Mathar, Nov 05 2016

Links

R. J. Mathar, Table of n, a(n) for n = 1..419

R. J. Mathar, Factorizations of integers into factors with distinct bases and exponents

Index to sequences related to prime signature

Formula

a(n)=1 for all n in A005117. a(n)=2 for all n in A001248 and for all n in A054753 and for all n in A085987 and for all n in A030078. a(n)=3 for all n in A065036. a(n)=4 for all n in A085986 and for all n in A030514. a(n)=5 for all n in A178739, all n in A179644 and for all n in A050997. a(n)=6 for all n in A143610, all n in A162142 and all n in A178740. a(n)=7 for all n in A030516. a(n)=9 for all n in A189988 and all n in A189987. a(n)=10 for all n in A092759. a(n) = 11 for all n in A179664. a(n)=12 for all n in A179646. - R. J. Mathar, Nov 05 2016, May 20 2017

Example

From R. J. Mathar, Nov 05 2016: (Start)
a(4)=2: 4^1 = 2^2.
a(8)=2: 8^1 = 2^3.
a(9)=2: 9^1 = 3^2.
a(12)=2: 12^1 = 2^2*3^1.
a(16)=4: 16^1 = 4^2 = 2^2*4^1 = 2^4.
a(18)=2: 18^1 = 2*3^2.
a(20)=2: 20^1 = 2^2*5^1.
a(24)=3: 24^1 = 2^2*6^1 = 2^3*3^1.
a(32)=5: 32^1 = 2^1*4^2 = 2^2*8^1 = 2^3*4^1 = 2^5.
a(36)=4: 36^1 = 6^2 = 3^2*4^1 = 2^2*9^1.
a(48)=5: 48^1 = 3^1*4^2 = 2^2*12^1 = 2^3*6^1 = 2^4*3^1.
a(60)=2 : 60^1 = 2^2*15^1.
a(64)=7: 64^1 = 8^2 = 4^3 = 2^2*16^1 = 2^3*8^1 = 2^4*4^1 = 2^6.
a(72)=6 : 72^1 = 3^2*8^1 = 2^1*6^2 = 2^2*18^1 = 2^3*9^1 = 2^3*3^2.
(End)

Maple

# Count solutions for products if n = dvs_i^exps(i) where i=1..pividx are fixed
Apiv := proc(n, dvs, exps, pividx)
    local dvscnt, expscopy, i, a, expsrt, e ;
    dvscnt := nops(dvs) ;
    a := 0 ;
    if pividx > dvscnt then
        # have exhausted the exponent list: leave of the recursion
        # check that dvs_i^exps(i) is a representation
        if n = mul( op(i, dvs)^op(i, exps), i=1..dvscnt) then
            # construct list of non-0 exponents
            expsrt := [];
            for i from 1 to dvscnt do
                if op(i, exps) > 0 then
                    expsrt := [op(expsrt), op(i, exps)] ;
                end if;
            end do;
            # check that list is duplicate-free
            if nops(expsrt) = nops( convert(expsrt, set)) then
                return 1;
            else
                return 0;
            end if;
        else
            return 0 ;
        end if;
    end if;
    # need a local copy of the list to modify it
    expscopy := [] ;
    for i from 1 to nops(exps) do
        expscopy := [op(expscopy), op(i, exps)] ;
    end do:
    # loop over all exponents assigned to the next base in the list.
    for e from 0 do
        candf := op(pividx, dvs)^e ;
        if modp(n, candf) <> 0 then
            break;
        end if;
        # assign e to the local copy of exponents
        expscopy := subsop(pividx=e, expscopy) ;
        a := a+procname(n, dvs, expscopy, pividx+1) ;
    end do:
    return a;
end proc:
A255231 := proc(n)
    local dvs, dvscnt, exps ;
    if n = 1 then
        return 1;
    end if;
    # candidates for the bases are all divisors except 1
    dvs := convert(numtheory[divisors](n) minus {1}, list) ;
    dvscnt := nops(dvs) ;
    # list of exponents starts at all-0 and is
    # increased recursively
    exps := [seq(0, e=1..dvscnt)] ;
    # take any subset of dvs for the bases, i.e. exponents 0 upwards
    Apiv(n, dvs, exps, 1) ;
end proc:
seq(A255231(n), n=1..120) ; # R. J. Mathar, Nov 05 2016

Crossrefs

Cf. A000688 (b_i not necessarily distinct).

Cf. A001248, A005117, A030078, A030514, A054753, A065036, A085986, A085987, A143610, A178739.

Sequence in context: A050377 A344417 A347437 * A363265 A347456 A294874

Adjacent sequences: A255228 A255229 A255230 * A255232 A255233 A255234

Keyword

nonn

Author

Saverio Picozzi, Feb 18 2015

Extensions

Values corrected. Incorrect comments removed. - R. J. Mathar, Nov 05 2016

Status

approved