|
|
FORMULA
|
a(n) = Sum_{k=0..n} binomial(n,k) * k*(k+1)^(k-1) * n^(n-k-1) for n>0 with a(0)=1.
E.g.f. A(x) satisfies:
(1) A(x) = W(x*W(x)), where W(x) = LambertW(-x)/(-x) = Sum_{n>=0} (n+1)^(n-1)*x^n/n!.
(2) A(x) = exp( T(T(x)) ), where T(x) = -LambertW(-x) is Euler's tree function (A000169).
(3) A(x) = exp( -A(x)*LambertW(-x) ).
(4) A(x) = ( LambertW(-x)/(-x) )^A(x).
(5) A(x) = ( Sum_{n>=0} (n+1)^(n-1)*x^n/n! )^A(x).
(6) A(x) = Sum_{n>=0} A(x)*(n + A(x))^(n-1) * x^n/n!.
(7) A(x)^m = Sum_{n>=0} m*A(x)*(n + m*A(x))^(n-1) * x^n/n!.
(8) A(x/exp(x)) = exp(T(x)) = LambertW(-x)/(-x).
(9) log(A(x)) = A(x) * Sum_{n>=1} n^(n-1) * x^n/n!, and equals the e.g.f. of A207833.
(10) A(x) = 1 + Sum_{n>=1} (n+1)^(n-1)*x^n/n! * Sum_{k>=0} n*(k+n)^(k-1)*x^k/k!.
a(n) ~ n! * (-exp((1+exp(-1))*n)/(sqrt(2*Pi*(1-exp(-1)))*n^(3/2) *LambertW(-exp(-1-exp(-1))))). - Vaclav Kotesovec, Jul 05 2013
|
|
|
EXAMPLE
|
E.g.f.: A(x) = 1 + x + 5*x^2/2! + 43*x^3/3! + 525*x^4/4! + 8321*x^5/5! +...
Define W(x) = LambertW(-x)/(-x), where W(x) = exp(x*W(x)) and begins:
W(x) = 1 + x + 3*x^2/2! + 4^2*x^3/3! + 5^3*x^4/4! + 6^4*x^5/5! +...
then
(1) A(x) = W(x*W(x)),
(4) A(x) = W(x)^A(x),
(3) A(x) = exp( x*A(x)*W(x) ),
(8) A(x/exp(x)) = W(x).
The e.g.f. also satisfies:
(6) A(x) = 1 + A(x)*x + A(x)*(2 + A(x))*x^2/2! + A(x)*(3 + A(x))^2*x^3/3! + A(x)*(4 + A(x))^3*x^4/4! + A(x)*(5 + A(x))^4*x^5/5! +...
and, for all real m,
(7) A(x)^m = 1 + m*A(x)*(1+m*A(x))^0*x^1/1! + m*A(x)*(2+m*A(x))^1*x^2/2! + m*A(x)*(3+m*A(x))^2*x^3/3! + m*A(x)*(4+m*A(x))^3*x^4/4! + m*A(x)*(5+m*A(x))^4*x^5/5! +...
|
|
|
PROG
|
(PARI) {a(n) = if(n==0, 1, sum(k=0, n, binomial(n, k)*k*(k+1)^(k-1)*n^(n-k-1)))}
for(n=0, 20, print1(a(n), ", "))
(PARI) /* E.g.f.: A(x) = W(x*W(x)) */
{a(n)=local(W=sum(k=0, n, (k+1)^(k-1)*x^k/k!)+x*O(x^n)); n!*polcoeff(subst(W, x, x*W), n)}
(PARI) /* E.g.f.: A(x) = exp(T(T(x)) ) */
{a(n)=local(T=sum(k=1, n, k^(k-1)*x^k/k!)+x*O(x^n)); n!*polcoeff(exp(subst(T, x, T)), n)}
(PARI) /* E.g.f.: A(x) = exp( -A(x)*LambertW(-x) ) */
{a(n)=local(A=1+x, LambertW=sum(k=1, n, -k^(k-1)*(-x)^k/k!)+x*O(x^n));
for(i=1, n, A=exp(-A*subst(LambertW, x, -x) +x*O(x^n))); n!*polcoeff(A, n)}
(PARI) /* E.g.f.: A(x) = ( LambertW(-x)/(-x) )^A(x) */
{a(n)=local(A=1+x, W=sum(k=0, n, (k+1)^(k-1)*x^k/k!)+x*O(x^n));
for(i=1, n, A=W^A); n!*polcoeff(A, n)}
(PARI) /* E.g.f.: A(x) = Sum_{n>=0} A(x)*(n + A(x))^(n-1) * x^n/n!. */
{a(n)=local(A=1+x); for(i=1, n, A=sum(k=0, n, A*(k+A)^(k-1)*x^k/k!)+x*O(x^n)); n!*polcoeff(A, n)}
|
