A001664 Quadratic coefficient of the n-th converging polynomial of Weber functions. (Formerly M4165 N1732)

1, -6, 25, -60, -203, 3710, -21347, -50400, 2465969, -24201342, -14909791, 4154706556, -61829802067, 107889525510, 13926895008805, -296622934827816, 1387504872714793, 80367331405832714, -2381736125794455767, 19480923855903871284, 721535152036700012069, -29550684521199839783538

Offset

2,2

References

N. J. A. Sloane, A Handbook of Integer Sequences, Academic Press, 1973 (includes this sequence).

N. J. A. Sloane and Simon Plouffe, The Encyclopedia of Integer Sequences, Academic Press, 1995 (includes this sequence).

Links

Table of n, a(n) for n=2..23.

P. Wynn, Converging factors for the Weber parabolic cylinder functions of complex argument, part Ia, part Ib, Proc. Konin. Ned. Akad. Weten., Series A, 66 (1963), 721-754 (two parts). In (45) the factor p_{r-2,2} should read p_{r-2,1}.

P. Wynn, Converging factors for the Weber parabolic cylinder functions ... [Annotated scan of part 2 only]

Maple

# equation (47)
prs := proc(r, k)
    if r = 0  then
        1 ;
    elif r = 1  then
        -1+k ; # (38)
    elif r =2 then
        1-3*k+k^2 ;
    end if;
end proc:
p := proc(r, s)
    option remember ;
    local k, a, lambda, mu, phi, theta ;
    # theta := 0 ; # valid for Table VII
    phi :=1 : # (30) for theta=0
    a := 1/2 ; # specific in Table VII
    lambda := 2*(a-1) ; # (15)
    mu := (a-1/2)*(a-3/2) ; # (13)
    if r = s then
        return 1; # eq (42)
    elif s > r or s <0 then
        return 0 ;
    elif r <=2 then
        coeff(prs(r, k), k, s) ;
    elif s = 0 then
        # eq (46)
        2*(phi+2)*procname(r, 1) -8*procname(r, 2)
        +4*(4*r-lambda-2)*procname(r-1, 1)
        +2*(lambda*(phi+1)-2*(r-1)*phi-4*r)*procname(r-1, 0)
        -4*(mu-2*lambda*(r-1)+4*(r-1)^2)*procname(r-2, 0) ;
        return %/(phi+1) ;
    elif s = 1 then
        # eq (45)
        # note that the 2nd index of the last p is wrong in the publication
        4*(phi+2)*procname(r, 2) -24*procname(r, 3) # unreadable index is 3
        +8*(4*r-lambda-2)*procname(r-1, 2)
        -8*procname(r-1, 1)+2*(phi+2)*procname(r-1, 0)
        +2*(lambda*(phi+1)-2*(r-1)*phi-4*r)*procname(r-1, 1)
        -4*(lambda-4*r+4)*procname(r-2, 0)
        -4*(mu-2*lambda*(r-1)+4*(r-1)^2)*procname(r-2, 1) ;
        return %/(phi+1) ;
    elif s= r-1 then
        # eq (43)
        2*(phi+2)*r*procname(r, r) -8*(r-1)*procname(r-1, r-1)
        +2*(phi+2)*procname(r-1, r-2)+2*(lambda*(phi+1)-2*(r-1)*phi-4*r)*procname(r-1, r-1)
        -4*procname(r-2, r-3)-4*(lambda-4*r+4)*procname(r-2, r-2) ;
        return %/(phi+1) ;
    else
        # eq (44)
        2*(s+1)*(phi+2)*procname(r, s+1) -4*(s+1)*(s+2)*procname(r, s+2)
        +4*(4*r-lambda-2)*(s+1)*procname(r-1, s+1)-8*s*procname(r-1, s)
        +2*(phi+2)*procname(r-1, s-1)+2*(lambda*(phi+1)-2*(r-1)*phi-4*r)*procname(r-1, s)
        -4*procname(r-2, s-2)-4*(lambda-4*r+4)*procname(r-2, s-1)
        -4*(mu-2*lambda*(r-1)+4*(r-1)^2)*procname(r-2, s) ;
        return %/(phi+1) ;
    end if;
end proc:
A001664 := proc(n)
    p(n, 2) ;
end proc:
seq(A001664(n), n=2..30) ; # R. J. Mathar, Jan 13 2025

Crossrefs

Cf. A001663, A001662 (absolute coefficient)

Sequence in context: A065069 A319429 A022270 * A255687 A332698 A096958

Adjacent sequences: A001661 A001662 A001663 * A001665 A001666 A001667

Keyword

sign

Author

N. J. A. Sloane

Status

approved