A390229 a(n) is the least positive integer k with exactly n distinct prime factors such that, for every prime power p^e in the canonical prime factorization of k, (p + e) divides k.

1, 4, 12, 60, 840, 9240, 120120, 6126120, 116396280, 2677114440, 77636318760, 9626903526240, 356195430470880, 14604012649306080, 627972543920161440, 29514709564247587680, 4692838820715366441120, 276877490422206620026080, 16889526915754603821590880, 1131598303355558456046588960

Offset

0,2

Comments

Minimal k has the smallest n distinct prime factors: k = Product_{i = 1 .. n} prime(i)^e_i. Using any larger prime cannot reduce k, because the divisibility constraints force the other exponents to be at least as large as before, while the larger prime base makes the product no smaller. Choosing the minimal exponents e_i >= 1 that satisfy all (prime(i) + e_i) dividing k gives the minimal k.

Links

Felix Huber, Table of n, a(n) for n = 0..345

Example

a(4) = 840 = 2^3*3^1*5^1*7^1 is the least k with exactly 4 distinct prime factors such that (2 + 3) = 5, (3 + 1) = 4, (5 + 1) = 6, and (7 + 1) = 8 all divide 840.

Maple

with(NumberTheory):
A390229 := proc(n) option remember;
    local c, p, m, e, i, j, q, t, r, s;
    if n = 0 then return 1 fi;
    p := []; s := 2; while nops(p) < n do p := [op(p), s]; s := nextprime(s) end do;
    m := table(); for i to n do m[p[i]] := i end do;
    e := Array(1 .. n, 'fill = 1');
    do
        c := false;
        for i to n do
            do
                q := p[i] + e[i];
                t := ifactors(q)[2];
                s := true;
                for r in t do if r[1] > p[n] then s := false; break end if end do;
                if not s then
                    e[i] := e[i] + 1; c := true; next
                end if;
                s := true;
                for r in t do
                    j := m[r[1]];
                    if e[j] < r[2] then e[j] := r[2]; c := true; s := false end if
                end do;
                if s then break end if
            end do
        end do;
        if not c then break end if
    end do;
    mul(p[i]^e[i], i = 1 .. n)
end proc:
seq(A390229(n), n = 0 .. 19);

Crossrefs

Cf. A000040, A002110, A033950, A392819.

Sequence in context: A083484 A088860 A097250 * A188328 A291772 A222645

Adjacent sequences: A390226 A390227 A390228 * A390230 A390231 A390232

Keyword

nonn

Author

Felix Huber, Feb 23 2026

Status

approved