A339269 a(n) is the least number that is the product of n primes (not necessarily distinct) and is the sum of n consecutive primes, or 0 if there are none.

2, 0, 425, 36, 243, 756, 29889, 4704, 207765, 8448, 4465125, 108864, 13640319, 1022976, 146146275, 3010560, 6500054871, 4259840, 60767621145, 36864000, 454444233597, 167215104, 8664659236485, 796262400, 49362406764957, 7935623168, 2310430513712625, 4160749568, 4216955409197811, 28538044416

Offset

1,1

Comments

Conjecture: a(n) > 0 for every n > 2.

If n > 2 is odd, the sum of n consecutive odd primes is odd, so (if nonzero) a(n) >= 3^n.

Links

Robert Israel, Table of n, a(n) for n = 1..50

Formula

a(n) = A143121(A339185(n)+n, A339185(n)).

Example

a(3)=425 because 425 = 5^2*7 is the product of three primes and 425 = 137+139+149 is the sum of three consecutive primes, and no smaller number has this property.

Maple

sumofconsecprimes:= proc(x, n)
  local P, k, p, q, t;
  P:= nextprime(floor(x/n));
  p:= P; q:= P;
  for k from 1 to n-1 do
    if k::even or q = 2 then p:= nextprime(p); P:= P, p;
    else q:= prevprime(q); P:= q, P;
    fi
  od;
  P:= [P];
  t:= convert(P, `+`);
  if t = x then return P fi;
  if t > x then
    while t > x do
      if q = 2 then return false fi;
      q:= prevprime(q);
      t:= t + q - p;
      P:= [q, op(P[1..-2])];
      p:= P[-1];
      if t = x then return P fi;
    od
  else
    while t < x do
      p:= nextprime(p);
      t:= t + p - q;
      P:= [op(P[2..-1]), p];
      q:= P[1];
      if t = x then return P fi;
    od
  fi;
  false
end proc:
children:= proc(r) local L, x, p, q, t, R;
  x:= r[1];
  L:= r[2];
  t:= L[-1];
  p:= t[1]; q:= nextprime(p);
  if t[2]=1 then t:= [q, 1];
  else t:= [p, t[2]-1], [q, 1]
  fi;
  R:= [x*q/p, [op(L[1..-2]), t]];
  if nops(L) >= 2 then
    p:= L[-2][1];
    q:= L[-1][1];
    if L[-2][2]=1 then t:= [q, L[-1][2]+1]
    else t:= [p, L[-2][2]-1], [q, L[-1][2]+1]
    fi;
    R:= R, [x*q/p, [op(L[1..-3]), t]]
  fi;
  [R]
end proc:
f:= proc(n) local Q, t, x, v;
      uses priqueue;
      initialize(Q);
      if n::even then insert([-2^n, [[2, n]]], Q)
      else insert([-3^n, [[3, n]]], Q)
      fi;
      do
        t:= extract(Q);
        x:= -t[1];
        v:= sumofconsecprimes(x, n);
        if v <> false then return x fi;
        for t in children(t) do insert(t, Q) od;
      od
   end proc:
f(1):= 2:
f(2):= 0:
map(f, [$1..34]);

Crossrefs

Cf. A001222, A143121, A339185.

Sequence in context: A324687 A012755 A012452 * A013417 A013418 A259435

Adjacent sequences: A339266 A339267 A339268 * A339270 A339271 A339272

Keyword

nonn

Author

J. M. Bergot and Robert Israel, Nov 29 2020

Status

approved