A260645 - OEIS

%I #24 Nov 10 2021 07:31:32

%S 1,1,5,19,19,5,41,385,231,19,109,95,155,41,95,41387,271,231,341,361,

%T 205,109,505,1925,3337,155,36118,779,811,95,929,19823665,545,271,779,

%U 4389,1331,341,775,7315,1639,205,1805,2071,4389,505,2161,206935,18099,3337,1355,2945,2755,36118,2071,15785,1705,811,3421,1805,3659,929,9471

%N The number of central quasigroups (also known as T-quasigroups, or quasigroups affine over an abelian group) of order n, up to isomorphism.

%C A quasigroup (G,*) is called central if it admits an affine representation over an abelian group (G,+), that is, if x*y = f(x)+g(y)+c where f,g are automorphisms of (G,+) and c in G.

%H David Stanovsky, <a href="/A260645/b260645.txt">Table of n, a(n) for n = 1..63</a>

%H David Stanovský and Petr Vojtechovský, <a href="http://arxiv.org/abs/1511.03534">Central and medial quasigroups of small order</a>, arxiv preprint arXiv:1511.03534 [math.GR], 2015.

%o (GAP) # gives the number of central quasigroups over SmallGroup(n, k)

%o LoadPackage("loops");

%o CQ := function( n, k )

%o     local G, ct, elms, inv, A, f_reps, count,f, Cf, O, g_reps, g, Cfg, W, unused, c, Wc;

%o     G := SmallGroup( n, k );

%o     G := IntoLoop( G );

%o     ct := CayleyTable( G );

%o     elms := Elements( G );

%o     inv := List( List( [1..n], i -> elms[i]^(-1) ), x -> x![1] );

%o     A := AutomorphismGroup( G );

%o     f_reps := List( ConjugacyClasses( A ), Representative );

%o     count := 0;

%o     for f in f_reps do

%o         Cf := Centralizer( A, f );

%o         O := OrbitsDomain( Cf, A );

%o         g_reps := List( O, x -> x[1] );

%o         for g in g_reps do

%o             Cfg := Intersection( Cf, Centralizer( A, g ) );

%o             W := Set( [1..n], w -> ct[w][ inv[ ct[w^f][w^g] ] ] );

%o             unused := [1..n];

%o             while not IsEmpty( unused ) do

%o                 c := unused[1];

%o                 count := count + 1;

%o                 if Size(W) = Length(unused) then

%o                     unused := [];

%o                 else

%o                     Wc := Set( W, w -> ct[w][c] );

%o                     Wc := Union( Orbits( Cfg, Wc ) );

%o                     unused := Difference( unused, Wc );

%o                 fi;

%o             od;

%o         od;

%o     od;

%o     return count;

%o end;

%Y Cf. A226193.

%K nonn,hard,mult

%O 1,3

%A _David Stanovsky_, Nov 12 2015