\\ Auxiliary function, assumes points on boundary are outside.
\\ This is conservative for finding the maximum number of covered
\\ grid points. Results for the minimum number must, at least in theory,
\\ be checked to see if they depend on an exact location
\\ of grid points on the boundary.
inrot(x,y,w,h,sp,cp) = {my (xr=x*cp+y*sp, yr=-x*sp+y*cp);
                       xr>0 && xr<w && yr>0 && yr<h };

a354702_4(w,h,repeat=100000,verbose=1) = {my (limit=ceil(1.5*max(w,h)),
                                              cmin=oo, cmax=0);
  for ( k = 1, repeat,
       my (phi=Pi*random(1.0)/2, sp=sin(phi), cp=cos(phi),
          dx=random(1.0),
          dy=random(1.0),
          n=0);
    for ( x0 = 0, limit,
         my (nlx=0, xstep=max(1, x0+x0));
      forstep( x = -x0, x0, xstep,
           for ( y = -1, limit,
                my (xx=x+dx, yy=y+dy, inr=inrot(xx,yy,w,h,sp,cp));
                  n+=inr; nlx+=inr
               )
             );
         if(nlx==0,next)
        );
        if (n < cmin, if(verbose,print([-n,dx,dy,phi])); cmin=n);
        if (n > cmax, if(verbose,print([n,dx,dy,phi]));  cmax=n)
      );
  [cmin, cmax] };

\\ Examples of calls
\\ a354702_4(7,3) should return [18, 25]
\\ for(n=1,10,print1(a354702_4(n,n,20000,0)[1],", "))
\\ provides upper bounds for A293330, but, be warned:
\\ 20000 reps is far too few to get stable results.