\\ Kevin Ryde, March 2022
\\
\\ Usage; gp <a352288.gp
\\
\\ This is some PARI/GP code calculating an individual term of A352288, the
\\ total cophenetic index of the rooted tree with Matula-Goebel number n.

default(recover,0)
default(strictargs,1)

{
  my(TC(n) = if(n==1, [0,1],
                my(f=factor(n),tc);
                [ (tc=self()(primepi(p))) + [binomial(tc[2],2), 0]
                 | p<-f[,1]]   \\ each prime
                * f[,2]));     \\ repetitions by scalar product

  a(n) = TC(n)[1];
}
{
  print1("A352288 = ");
  for(n=1,25, print1(a(n),","));
  print("...");
}

\\ The method follows the formula in the sequence, with recursion to descend
\\ to calculate subtrees.  TC() returns a vector of two values
\\
\\    TC(n) = [ total cophenetic index of tree n,
\\              number of childless vertices in tree n
\\            ]
\\
\\ In a subtree like
\\
\\              root
\\            /     \ \
\\         subtree   ....
\\
\\ a(subtree) measures depths of common ancestors only up to the top of that
\\ subtree.  To measure up to the root, must add +1 for each childless pair
\\ in the subtree, which is the binomial(tc[2],2) in TC().
\\
\\ factor() gives prime factors as p^reps.  Repetitions of subtree p are as
\\ easy as multiplying both its total cophenetic index and its number of
\\ childless vertices.  The scalar product "[ vector ]*f[,2]" is a
\\ convenient way to do that.

\\-----------------------------------------------------------------------------

\\ For interest, Mir, Rossello, and Rotger, consider the largest total
\\ cophenetic index among phylogenic trees.  Phylogenic trees are
\\ series-reduced so no vertex has exactly 1 child.
\\
\\ They show that the largest index for the trees of a given number of
\\ childless vertices is the rooted caterpillar with one child each vertex
\\ until the deepest, as per A352289.  For example
\\
\\           R        root R
\\          / \       spine s
\\         s   c      n=4 childless vertices "c"
\\        / \
\\       s   c
\\      / \
\\     c   c
\\
\\ For n childless vertices, the total cophenetic index is binomial(n,3).

A352289(n) =
{
  n>=1 || error();
  my(ret=1);  \\ singleton childless vertex
  for(i=2,n,
     ret = 2*prime(ret));  \\ new root and its child
  ret;
}
{
  for(n=1,8,
     my(primecode=A352289(n));
     a(primecode) == binomial(n,3)  || error());
}

\\-----------------------------------------------------------------------------
print("end");