Some notes on the link between A180389 and Schur polynomials.

A few definitions:

Partition1Q[arg_List]:=MatchQ[arg,{___Integer}]&&(arg=={}||Positive[1+Min[arg-Append[Rest[arg],0]]]);
    (* a replacement of the built-in test for partition format *)

hooklength[(\[Lambda]_)?Partition1Q] := Table[Count[\[Lambda], q_ /; q >= j] + 1 - i + \[Lambda][[i]] - j, {i, Length[\[Lambda]]}, {j, \[Lambda][[i]]}]; 
    (* used in formula to count Standard Young Tableaux of shape \[Lambda] *)

content[(\[Lambda]_)?Partition1Q] := Table[j - i, {i, Length[\[Lambda]]}, {j, \[Lambda][[i]]}]; 
    (* see http://www-math.mit.edu/~rstan/transparencies/hooks.pdf *)

stanley[(\[Lambda]_)?Partition1Q, t_Integer] := Times @@ ((t + Flatten[content[\[Lambda]]])/Flatten[hooklength[\[Lambda]]]);
    (* counts Semi Standard Young Tableaux of shape [\Lambda] with max entry = t *)

hookvector[(par_)?PartitionQ] := Block[{res = {0}, le = Tr[par]}, Table[AppendTo[res, stanley[par, v] - Coefficient[Series[x^Range[0, v - 1] . res/
           (1 - x)^(le + 1), {x, 0, v}], x^v]], {v, le}]; Rest[res]]; 
    (* coefficient list of the numerator of the GF (remark that it sums to the # of SYT) *)

countDescents[perm_List]:=Count[Sign[Rest[perm]-Drop[perm,-1]],-1];
    (* counts descents in a permutation *)

In the table below, we see for each partition of n=6 :
    the # of SSYT with max entry t= 1 .. 2n (or the number of terms in the Schur polynomial in t variables);
    the numerator of the GF for the previous column (denominator is always (1-x)^(n+1) );
    the # of SYT using the hooklength formula (Frame, Robinson, Thrall);
    its square;
    the 'hookvector' : coefficient list of the GF (remark that it sums to the # of SYT);
    the previous with each coefficient squared;

n=6;{#, it=Table[stanley[#,j],{j,2n}] ,Expand[Simplify[FindGeneratingFunction[it,x](1-x)^(n+1)]],it=n!/Apply[Times,Flatten[hooklength[#]]],it^2,hookvector[#],hookvector[#]^2}&/@Partitions[n]//Grid

{6}	        {1,7,28,84,210,462,924,1716,3003,5005,8008,12376}	1	        1	1	{1,0,0,0,0,0}	{1,0,0,0,0,0}
{5,1}	        {0,5,35,140,420,1050,2310,4620,8580,15015,25025,40040}	5 x	        5	25	{0,5,0,0,0,0}	{0,25,0,0,0,0}
{4,2}	        {0,3,27,126,420,1134,2646,5544,10692,19305,33033,54054}	3 x+6 x^2	9	81	{0,3,6,0,0,0}	{0,9,36,0,0,0}
{4,1,1}	        {0,0,10,70,280,840,2100,4620,9240,17160,30030,50050}	10 x^2	        10	100	{0,0,10,0,0,0}	{0,0,100,0,0,0}
{3,3}	        {0,1,10,50,175,490,1176,2520,4950,9075,15730,26026}	x+3 x^2+x^3	5	25	{0,1,3,1,0,0}	{0,1,9,1,0,0}
{3,2,1}	        {0,0,8,64,280,896,2352,5376,11088,21120,37752,64064}	8 x^2+8 x^3	16	256	{0,0,8,8,0,0}	{0,0,64,64,0,0}
{3,1,1,1}	{0,0,0,10,70,280,840,2100,4620,9240,17160,30030}	10 x^3	        10	100	{0,0,0,10,0,0}	{0,0,0,100,0,0}
{2,2,2}	        {0,0,1,10,50,175,490,1176,2520,4950,9075,15730}	        x^2+3 x^3+x^4	5	25	{0,0,1,3,1,0}	{0,0,1,9,1,0}
{2,2,1,1}	{0,0,0,6,45,189,588,1512,3402,6930,13068,23166}	        6 x^3+3 x^4	9	81	{0,0,0,6,3,0}	{0,0,0,36,9,0}
{2,1,1,1,1}	{0,0,0,0,5,35,140,420,1050,2310,4620,8580}	        5 x^4	        5	25	{0,0,0,0,5,0}	{0,0,0,0,25,0}
{1,1,1,1,1,1}	{0,0,0,0,0,1,7,28,84,210,462,924}	                x^5	        1	1	{0,0,0,0,0,1}	{0,0,0,0,0,1}

Adding the last four columns gives:

Total[Take[#,-4]&/@ First[%] ]

{76,    720,    {1,9,28,28,9,1},      {1,35,210,210,35,1}  }

where the sum of # of SYT = 76 = # of involutions among the permutations of n=6;
the sum of the squares of the # of SYT equals n! = 720 (RSK alias 'bumping' algorithm)
the sum of the coefficient lists (alias 'hook vectors') also generated by
    Table[Normal[Series[(1-t)^(n+1) Sum[t^r Sum[Binomial[r (r+1)/2+k-1,k] Binomial[r+n-2k,n-2k],{k,0,Floor[n/2]}],{r,0,\[Infinity]}],{t,0,10}]],{n,10}]
the sum of the squared coefficients, also generated by (your binomial formula) :
    Table[   Table   [Sum[  Sum[(-1)^(i+j)*Binomial[n+1,i]*Binomial[n+1,j]*Binomial[(m-i)*(m-j)+n-1,n],{i,0,m}],{j,0,m}],{m,0,n+1}],{n,0,7}]

Remark that the 'hook vectors' also give the classification of involutions by # of descents:
    Table[Count[countDescents/@(TableauxToPermutation[#,#]&/@Tableaux[par]),#]&/@Range[0,n-1],{par,Partitions[n]}]//Grid

and that last observation takes the mystery away about the relation of the above to rises/descents in permutations/involutions.

Wouter, 2015/06/11