\\ Number of maximal subsets of {1..n} containing no products of distinct elements.
\\ Main recursive function has the following arguments:
\\    k: Indicates elements from 2..k have been picked.
\\    b: bitmap of chosen elements.
\\    ep: bitmap of products of distinct elements of b.
\\ Optimisation: Once elements 1..n\2 are selected we just add all elements > n\2 that
\\ are not a product of distinct elements already chosen.
A325710(n)={
   \\ test for maximality
    my(ismaxl(b, ep)=
      for(k=2, n\2, if(!bittest(ep,k), 
        my(f=0);
        for(i=2, n\k, if(bittest(ep,i) && bittest(b,k*i), f=1; break));
        if(!f, return(0));
       ));
      1
    );
    \\ main recursion
    my(recurse(k, b, ep)=
    k++;
    if(k > n\2, ismaxl(bitor(b, bitnegimply((2<<n)-(2<<(n\2)), ep)), ep), 
      my(t = self()(k, b, ep));
      if(!bittest(ep,k),
         forstep(i=n\k, 1, -1, if(bittest(ep,i), ep=bitor(ep,1<<(k*i))));
         t += self()(k, b + (1<<k), ep);
      );
      t);
   );
   1 + if(n > 1, recurse(1, 2, 2));
}

\\ End