A246883 G.f.: Sum_{n>=0} x^n * Sum_{k=0..n} C(n,k)^2 * x^(3*k).

1, 1, 1, 1, 2, 5, 10, 17, 27, 46, 86, 165, 308, 558, 1006, 1841, 3421, 6383, 11863, 21966, 40697, 75662, 141099, 263429, 491778, 918104, 1715259, 3208078, 6005818, 11250198, 21082487, 39524241, 74135187, 139128897, 261228200, 490682127, 922015964, 1733127107, 3258939997, 6130162494, 11534742080

Offset

0,5

Comments

Limit a(n)/a(n+1) = t^2 = 0.524888598656404... (A072223) where t is the positive real root of 1 - x - x^4 = 0.

Links

Michael De Vlieger, Table of n, a(n) for n = 0..1000

Hacène Belbachir and Abdelghani Mehdaoui, Recurrence relation associated with the sums of square binomial coefficients, Quaestiones Mathematicae (2021) Vol. 44, Issue 5, 615-624.

Formula

G.f.: Sum_{n>=0} (2*n)!/(n!)^2 * x^(4*n) / (1 - x + x^4)^(2*n+1). - Paul D. Hanna, Oct 15 2014

G.f.: Sum_{n>=0} x^n * [Sum_{k>=0} C(n+k,k)^2 * x^(3*k)] * (1-x^3)^(2*n+1).

G.f.: Sum_{n>=0} x^(4*n) * [Sum_{k>=0} C(n+k,k)^2 * x^k].

G.f.: Sum_{n>=0} x^(4*n) * [Sum_{k=0..n} C(n,k)^2 * x^k] /(1-x)^(2n+1).

G.f.: exp( Sum_{n>=1} (x^n/n) * Sum_{k=0..n} C(2*n,2*k) * x^(3*k) ).

G.f.: 1 / sqrt((1 - x + 2*x^2 + x^4)*(1 - x - 2*x^2 + x^4)).

G.f.: 1 / sqrt((1 - x + x^4)^2 - 4*x^4).

G.f.: 1 / sqrt((1 - x - x^4)^2 - 4*x^5).

a(n) = Sum_{k=0..[n/3]} C(n-3*k, k)^2.

Example

G.f.: A(x) = 1 + x + x^2 + x^3 + 2*x^4 + 5*x^5 + 10*x^6 + 17*x^7 +...
where, by definition,
A(x) = 1 + x*(1 + x^3) + x^2*(1 + 2^2*x^3 + x^6)
+ x^3*(1 + 3^2*x^3 + 3^2*x^6 + x^9)
+ x^4*(1 + 4^2*x^3 + 6^2*x^6 + 4^2*x^9 + x^12)
+ x^5*(1 + 5^2*x^3 + 10^2*x^6 + 10^2*x^9 + 5^2*x^12 + x^15) +...
which is also given by the series identity:
A(x) = 1/(1-x+x^4) + 2*x^4/(1-x+x^4)^3 + 6*x^8/(1-x+x^4)^5 + 20*x^12/(1-x+x^4)^7 + 70*x^16/(1-x+x^4)^9 + 252*x^20/(1-x+x^4)^11 + 924*x^24/(1-x+x^4)^13 +...
The logarithm of the g.f. begins:
log(A(x)) = x*(1 + x^3) + x^2*(1 + 6*x^3 + x^6)/2
+ x^3*(1 + 15*x^3 + 15*x^6 + x^9)/3
+ x^4*(1 + 28*x^3 + 70*x^6 + 28*x^9 + x^12)/4
+ x^5*(1 + 45*x^3 + 210*x^6 + 210*x^9 + 45*x^12 + x^15)/5 +...
more explicitly,
log(A(x)) = x + x^2/2 + x^3/3 + 5*x^4/4 + 16*x^5/5 + 31*x^6/6 + 50*x^7/7 + 77*x^8/8 + 145*x^9/9 + 306*x^10/10 + 628*x^11/11 + 1199*x^12/12 +...
where the logarithmic derivative equals
A'(x)/A(x) = (1-x+4*x^3+5*x^4-4*x^7)/((1-x+2*x^2+x^4)*(1-x-2*x^2+x^4)).

Mathematica

CoefficientList[Series[1/Sqrt[(1 - x + x^4)^2 - 4 x^4], {x, 0, 40}], x] (* Michael De Vlieger, Sep 10 2021 *)

Prog

(PARI) /* By definition: */
{a(n)=local(A=1); A=sum(m=0, n, x^m*sum(k=0, m, binomial(m, k)^2*x^(3*k)) +x*O(x^n)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From closed formula: */
{a(n)=local(A=1); A= 1/sqrt((1 - x + x^4)^2 - 4*x^4 +x*O(x^n)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From a series identity: */
{a(n)=local(A=1+x); A=sum(m=0, n, (2*m)!/(m!)^2 * x^(4*m) / (1 - x + x^4 +x*O(x^n))^(2*m+1)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From a binomial series identity: */
{a(n)=local(A=1+x); A=sum(m=0, n, x^m*(1-x^3)^(2*m+1)*sum(k=0, n, binomial(m+k, k)^2*x^(3*k)) +x*O(x^n)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From a binomial series identity: */
{a(n)=local(A=1+x); A=sum(m=0, n\4, x^(4*m)*sum(k=0, n-4*m, binomial(m+k, k)^2*x^k) +x*O(x^n)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From a binomial series identity: */
{a(n)=local(A=1+x); A=sum(m=0, n\4, x^(4*m) * sum(k=0, m, binomial(m, k)^2*x^k) / (1-x +x*O(x^n))^(2*m+1) ); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From exponential formula: */
{a(n)=local(A=1); A=exp(sum(m=1, n, sum(k=0, m, binomial(2*m, 2*k)*x^(3*k)) * x^m/m) +x*O(x^n)); polcoeff(A, n)}
for(n=0, 40, print1(a(n), ", "))
(PARI) /* From formula for a(n): */
{a(n)=sum(k=0, n\3, binomial(n-3*k, k)^2)}
for(n=0, 40, print1(a(n), ", "))

Crossrefs

Cf. A072223, A181665, A246840, A246884, A248193.

Sequence in context: A119114 A062493 A056871 * A329864 A174910 A363072

Adjacent sequences: A246880 A246881 A246882 * A246884 A246885 A246886

Keyword

nonn

Author

Paul D. Hanna, Sep 06 2014

Status

approved